用 Pine Script 寫自訂指標
均線交叉、RSI、KD

看完 Pine Script 入門 會畫一條均線後，這篇給你三個最常用的實作範例：均線黃金交叉（含標記與警示）、RSI、KD。程式都用 v6 語法，複製貼進 TradingView 的 Pine 編輯器、按「新增到圖表」就能跑。

範例一：均線黃金交叉（標記 + 警示）

畫出快線與慢線，並在黃金交叉（快線由下往上穿過慢線）時標一個向上箭頭、死亡交叉標向下箭頭，最後加一個警示條件：

//@version=6
indicator("均線黃金交叉", overlay = true)

fastLen = input.int(5,  "快線天數")
slowLen = input.int(20, "慢線天數")

fast = ta.sma(close, fastLen)
slow = ta.sma(close, slowLen)

plot(fast, "快線", color = color.red,  linewidth = 2)
plot(slow, "慢線", color = color.blue, linewidth = 2)

golden = ta.crossover(fast, slow)
death  = ta.crossunder(fast, slow)

plotshape(golden, title = "黃金交叉", style = shape.triangleup,
          location = location.belowbar, color = color.red,   size = size.small)
plotshape(death,  title = "死亡交叉", style = shape.triangledown,
          location = location.abovebar, color = color.green, size = size.small)

alertcondition(golden, title = "黃金交叉", message = "出現黃金交叉！")

＊台股紅漲綠跌，所以這裡黃金交叉用紅色、死亡交叉用綠色。

重點函式：ta.crossover(a, b) 在 a 由下往上穿過 b 時回傳 true；ta.crossunder 相反。plotshape 負責在圖上畫箭頭；alertcondition 建立一個警示條件——存檔後在圖表上按「鬧鐘」新增警示，就能在交叉時收到通知。

範例二：RSI（畫在副圖）

RSI 不是畫在 K 線上，而是獨立副圖，所以把 overlay 設成 false：

//@version=6
indicator("我的 RSI", overlay = false)

length = input.int(14, "RSI 期數")
rsi = ta.rsi(close, length)

plot(rsi, "RSI", color = color.purple, linewidth = 2)
hline(70, "超買", color = color.gray)
hline(30, "超賣", color = color.gray)

＊hline 畫水平參考線；一般 RSI > 70 視為超買、< 30 視為超賣（RSI 怎麼看）。

範例三：KD（隨機指標，副圖）

先用 ta.stoch 取得 RSV，再平滑成 K 與 D：

//@version=6
indicator("我的 KD", overlay = false)

length = input.int(9, "RSV 期數")
rsv = ta.stoch(close, high, low, length)
k = ta.sma(rsv, 3)
d = ta.sma(k, 3)

plot(k, "K", color = color.blue,   linewidth = 2)
plot(d, "D", color = color.orange, linewidth = 2)
hline(80, "超買", color = color.gray)
hline(20, "超賣", color = color.gray)

//@version=6
indicator("台股式 KD (9,3,3)", overlay = false)

length = input.int(9, "RSV 期數")
rsv = ta.stoch(close, high, low, length)

var float k = na
var float d = na
k := na(k[1]) ? 50.0 : k[1] * 2 / 3 + rsv / 3
d := na(d[1]) ? 50.0 : d[1] * 2 / 3 + k / 3

plot(k, "K", color = color.blue,   linewidth = 2)
plot(d, "D", color = color.orange, linewidth = 2)